新浪博客

[转载]测量等值的Mplus检验程序

2017-12-31 17:49阅读：

http://blog.sina.cn/dpool/blog/u/1085648655

原文地址：测量等值的Mplus检验程序
原文作者：Mpluscollege

多组测量等值的Mplus检验步骤列在表7-1中，仍然以PTSD为例。
表7-1 多组不变性的Mplus语句
形态不变性：
TITLE: This is an example of a Configural invariance test for continuous factor indicators
DATA: FILE IS PTSD gender.dat;
VARIABLE: Names are group y1-y17;
Grouping is Group (1=G1 2=G2);!
通过grouping命令定义两个或多个比较组，数据文件中group变量中的1代表第一组，2代表第二组；更多组（3组以上）的设置方法类似。注意这里使用的是单一数据文件即不同组的数据通过Grouping语句区分。
ANALYSIS: ESTIMATOR = MLM;
MODEL: F1 BY y1 y2 y3 y4 y5;
F2 BY y6 y7;
F3 BY y8 y9 y10 y11 y12;
F4 BY y13 y14 y15 y16 y17;
MODEL G2: !因为在Mplus多组分析时，默认因子负荷和指标截距等值，
所以通过设置“MODEL G2”来改变默认设置，凡是在其之下的语句均表示与其他组不同，这里是与G1组不同；
F1 BY y2 y3 y4 y5; !G2组中f1-f4指标因子负荷自由估计，释放弱等值限制；
F2 BY y7;
F3 BY y9 y10 y11 y12;
F4 BY y14 y15 y16 y17;
[y2-y5 y7 y9-y12 y14-y17]; !G2组中指标截距自由估计，释放强等值限制；

加设单位不变性或弱不变性：
!G2组中的因子负荷自由估计的设定被移除即还原因子负荷默认两组相等；
MODEL g2:
[y2-y5 y7 y9-y15 y17];

加设强不变性：
MODEL: F1 BY y1 y2 y3 y4 y5;
F2 BY y6 y7;
F3 BY y8 y9 y10 y11 y12;
F4 BY y13 y14 y15 y16 y17;
MODEL g2:
!“MODEL G2”中的所有设定被移除即恢复Mplus默认为设置即因子负荷和指标截距限定两组相等；

加设误差方差不变性或严格不变性：
MODEL: F1 BY y1 y2 y3 y4 y5;
F2 BY y6 y7;
F3 BY y8 y9 y10 y11 y12;
F4 BY y13 y14 y15 y16 y17;
y1-y17(1-17) !增加了误差方差两组相等的限制，
即通过括号内的标签设定两者相等；
加设因子方差-协方差不变性：
MODEL: F1 BY y1* y2 y3 y4 y5;
F2 BY y6* y7;
F3 BY y8* y9 y10 y11 y12;
F4 BY y13* y14 y15 y16 y17;
F1-F4@1; !通过固定因子方差为1来设定两组等值，这时每个因子第一个条目负荷设置为1的默认设定需要解除，即在y1 y6 y8 y13后加*；
F1 with F2-F4(2-4); !因子协方差设定相等；
F2 with F3-F4(5-6);
F3 with F4(7);
y1-y17(1-17);

加设因子潜均值不变性：
MODEL: F1 BY y1* y2 y3 y4 y5;
F2 BY y6* y7;
F3 BY y8* y9 y10 y11 y12;
F4 BY y13* y14 y15 y16 y17;
[F1@0]; [F2@0]; [F3@0]; [F4@0]; !因为参照组(第1组)的因子均值默认设定为0，所以只要设定所有组因子均值为0即设定各组因子均值相等；
F1-F4@1;
F1 with F2-F4(2-4);
F2 with F3-F4(5-6);
F3 with F4(7);
y1-y17(1-17);

误差方差协方差不变性的另外一种设置：
MODEL: F1 BY y1 y2 y3 y4 y5;
F2 BY y6 y7;
F3 BY y8 y9 y10 y11 y12;
F4 BY y13 y14 y15 y16 y17;
y1-y17@1; !设定误差采用简写形成表达；
MODEL G2:
y1-y17@1; !前面提到在MODEL G2中出现的设定均为个别组特有的设定，这里将误差方差设定为1与MODEL中设定的一致即等价于在MODEL中设定 “y1-y17(1-17);”

潜均值差异不变性的另外一种设置：
MODEL: F1 BY y1* y2 y3 y4 y5;
F2 BY y6* y7;
F3 BY y8* y9 y10 y11 y12;
F4 BY y13* y14 y15 y16 y17;
[F1@0]; [F2@0]; [F3@0]; [F4@0];
F1-F4@1;
F1 with F2-F4(2-4);
F2 with F3-F4(5-6);
F3 with F4(7);
MODEL G2:
y1-y17@1;
[F1@0]; [F2@0];
[F3@0]; [F4@0]; !因为参照组(第1组)的因子均值默认设定为0，所以在这里设定组特定因子均值为0即设定各组因子均值相等。如果存在第三组，则在MODEL g3中加设[F1@0]; [F2@0]; [F3@0]; [F4@0];
注：方框的是误差方差，由于不同学科对误差方差等值的要求是不一样的(Muthén & Muthén, 1998-2010)，所以可以设定等同也可以不做要求，具体依研究背景而定。
Mplus学习机会：
http://blog.sina.com.cn/s/blog_7fb03f7d01012fx1.html

我的更多文章

下载客户端阅读体验更佳

APP专享